***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 20, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAS70WS A K 
.param
+vc0 = 1.558e-5
+vc1 = 5.512e-5
+vc2 = 2.753e-6
+tc1 = 8.027e-2
+tc2 = 4.143e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3   
+is = 4.588e-9
+n = 1.098
+rs = 20
+ikf = 1e-3
+bv = 77 
***** capacitance parameter ***
+cjo = 1.766e-12
+m = 2.775e-1
+vj = 2.605e-1
+fc = 0.5  
***** temperature coefficient ***
+tnom = 25                     
+eg = 6.341e-1
+xti = 3 
+trs1 = -3.921e-3
+trs2 = -1.905e-5
+tikf = -6e-3
.ends BAS70WS
*$
